AutoHotKey(오토핫키) 설명서 FileAppend

→ AutoHotkey(을)를 유행시키는 페이지 → 레퍼런스 → FileAppend

FileAppend

텍스트 파일에 추가 기입.파일이 존재하지 않으면 작성된다.

FileAppend [, Text, Filename]

Parameters

인수명	설명
Text	추가 기입텍스트. 하늘의 신규 파일을 작성하고 싶은 경우는, 이 인수를 비운다.
Filename	추가 기입처의 파일명. 상대 패스로 지정했을 경우는,%A_WorkingDir%(을)를 기준으로 한 패스가 된다. 선두에 「*」(을)를 붙이면, 바이너리 모드로의 처리가 되어, 개행 코드의 자동변역을 하지 않는다. 파일명 대신에 「*」(을)를 지정하면, 표준 출력에 텍스트를 써낼 수 있다.

ErrorLevel

성공시는 「0」, 실패시는 「1」.

Related

FileRead, file-reading loop, FileReadLine, IniWrite, FileDelete

Example(s)

FileAppend, Another line.`n, C:\My Documents\Test.txt

; The following example uses a continuation section to enhance readability and maintainability:
FileAppend,
(
A line of text.
By default, the hard carriage return (Enter) between the previous line and this one will be written to the file.
	This line is indented with a tab; by default, that tab will also be written to the file.
Variable references such as %Var% are expanded by default.
), C:\My File.txt

; The following example demonstrates how to automate FTP uploading using the operating 
; system's built-in FTP command. This script has been tested on Windows XP and 98se.

FTPCommandFile = %A_ScriptDir%\FTPCommands.txt
FTPLogFile = %A_ScriptDir%\FTPLog.txt
FileDelete %FTPCommandFile%  ; In case previous run was terminated prematurely.

FileAppend,
(
open host.domain.com
username
password
binary
cd htdocs
put %VarContainingNameOfTargetFile%
delete SomeOtherFile.html
rename OldFileName.html NewFileName.html
ls -l
quit
), %FTPCommandFile%

RunWait %comspec% /c ftp.exe -s:"%FTPCommandFile%" >"%FTPLogFile%"
FileDelete %FTPCommandFile%  ; Delete for security reasons.
Run %FTPLogFile%  ; Display the log for review.

→ AutoHotkey(을)를 유행시키는 페이지 → 레퍼런스 → FileAppend